@echo off
setlocal EnableExtensions
chcp 65001 >nul

title Kvich Fjernsupport

set "KVICH_PSFILE=%TEMP%\Kvich-RustDesk-Setup-%RANDOM%-%RANDOM%.ps1"
set "KVICH_ORIGINAL_USERPROFILE=%USERPROFILE%"
set "KVICH_ORIGINAL_APPDATA=%APPDATA%"

echo.
echo Kvich Fjernsupport
echo =================
echo.
echo Henter den nyeste opsaetning fra help.kvich.dk...
echo.

powershell.exe -NoProfile -ExecutionPolicy Bypass -Command ^
  "$ErrorActionPreference='Stop';" ^
  "[Net.ServicePointManager]::SecurityProtocol=[Net.SecurityProtocolType]::Tls12;" ^
  "$p=$env:KVICH_PSFILE;" ^
  "Invoke-WebRequest -UseBasicParsing 'https://help.kvich.dk/setup.ps1' -OutFile $p;" ^
  "if(-not (Test-Path $p)){throw 'Filen blev ikke hentet.'};" ^
  "if((Get-Item $p).Length -lt 2000){throw 'Den hentede fil er uventet lille.'};" ^
  "$content=Get-Content -Raw $p;" ^
  "if($content -notmatch 'KVICH-RUSTDESK-SETUP-V2'){throw 'Den hentede fil er ikke en gyldig Kvich RustDesk-opsaetning.'}"

if errorlevel 1 (
    echo.
    echo FEJL: Kunne ikke hente eller validere opsaetningen.
    echo Intet er aendret paa denne computer.
    echo.
    del /q "%KVICH_PSFILE%" >nul 2>&1
    pause
    exit /b 1
)

powershell.exe ^
  -NoProfile ^
  -ExecutionPolicy Bypass ^
  -File "%KVICH_PSFILE%" ^
  -OriginalUserProfile "%KVICH_ORIGINAL_USERPROFILE%" ^
  -OriginalAppData "%KVICH_ORIGINAL_APPDATA%"

set "RESULT=%ERRORLEVEL%"

del /q "%KVICH_PSFILE%" >nul 2>&1

echo.

if "%RESULT%"=="0" (
    echo Kvich Fjernsupport er klar.
) else (
    echo Opsaetningen blev ikke gennemfoert.
)

echo.
pause

exit /b %RESULT%